$nomod51                ;der Modus fuer 8051 wird abgeschaltet
$debug
$nolist                 ;es wird kein Listing fuer reg535 erstellt
$include(reg535.pdf)    ;die 80535-spezifischen Daten
$list                   ;es wird ein Listing erstellt
$ title (20_SEK)
;------------------------------------------------------------------------
;Programmbeschreibung
;------------------------------------------------------------------------
;Programm: Erzeugt 1 Interrupt pro Sekunde ber die Dauer von 20 Sek.  
;          T1 startet die Funktion 
;          L1 leuchtet bei laufendem Betrieb
;          L2 blinkt mit 2 Sekunden Periodendauer
;Datum:  20.1.1996       
;Programmiert:  J. Walter 
;
;Verwendete Einspruenge: keine 
;
;Verwendete Unterprogramme: keine       
;
;
;Verwendete Register und Variable:
;Registerbank(0)        
;R2 Zaehlvariable fuer L2_DAUER*50ms             
;R3 Zaehlvariable fuer M_DAUER
;Kommentar: 
;
;Aenderungen:
;Datum:
;
;
;------------------------------------------------------------------------
;Initialisierungsteil fuer allgemeine Konstanten
;------------------------------------------------------------------------
L2_DAUER EQU 20
M_DAUER  EQU 20

CSEG AT 0H              ;Legt absolute Codesegmentadresse auf 0h
jmp INIT
;
;------------------------------------------------------------------------
;Interrupt-Vektoren
;------------------------------------------------------------------------
ORG 2BH                 ;Timer 2 Interrupt
TIMER2_INT:
call IR_SERVICE_T2
RETI
;------------------------------------------------------------------------
;Initialisierungsteil fuer On-Chip Peripherie
;------------------------------------------------------------------------
ORG 100H                ;Programmstart bei 100H
INIT:

;---------TIMER 2----T2CON------
clr T2PS                ;1/12 Oszillatorfrequenz
clr I3FR                ;wird nicht benoetigt
clr T2CM                ;Vergleich bei Ueberlauf
setb T2R1               ;Wiederladen bei Ueberlauf
clr T2R0
clr T2I1                ;Auswahl des Takteingangs
clr T2I0                ;vorerst nicht freigegeben

;---------INTERRUPT-FREIGABE----
mov IEN0,#10110000B     ;EAL, Serielle, T2 ist freigegeben

;------------------------------------------------------------------------
;Programmschleife
;------------------------------------------------------------------------

ABFRAGE:
jnb P1.1,SEK_20        ;Interrupt Service Routine laeuft
ajmp ABFRAGE

SEK_20:
;---------RELOAD-REGISTER-------
mov CRCH,#3CH           ;65536-50000=15536=#3CB0H
mov CRCL,#0B0H          ;50 ms Takt

;---------Zhlregister R2,R3----
mov R2,#L2_DAUER         ;20*50ms= 1 Sekunde
mov R3,#M_DAUER          ;20 Sekunden Messung

;---------TIMER 2 starten-------
setb T2I0               ;TIMER 2 laeuft
clr P3.2                ;Anzeige L1 Messung laeuft
jmp ABFRAGE

IR_SERVICE_T2:
clr TF2                 ; Flag TIMER 2 erkannt 
djnz R2,SPRUNG_1        ; 1 Sekunde vorbei ?
cpl P3.3                ; L2 ein 1 Sek, aus 1 Sek.
mov R2,#L2_DAUER         ; R2 20*50ms
djnz R3,SPRUNG_1        ; 20 Sekunden vorbei ?
mov R3,#M_DAUER          ; 20 wieder zuweisen
clr T2I0                ; TIMER 2 anhalten
setb P3.2
SPRUNG_1:
ret

end
